Регистр сведений как дополнение объекта

Публикация № 1238229

Разработка - Практика программирования

Регистры сведений справочники НСИ доработки структура данных интерфейс управляемые формы

Подключаем регистры сведений к формам связанных с ними объектов, быстро и надежно.

Лень – двигатель прогресса. Эту фразу любила повторять моя школьная преподаватель математики, и по совместительству директор школы, когда приводила примеры решения одной и той же задачи разными путями, один из которых выглядел много проще и короче остальных. Работа программиста в этот принцип вписывается как нельзя лучше. По большому счету, мы стремимся, чтобы система учета работала как часы, потому что лень заниматься поддержкой пользователей. Ведь гораздо удобнее, когда пользователь в поддержке не нуждается и не отвлекает лишний раз от более серьезных занятий, чем разбирательства с ошибкой в данных. Мы стремимся делать наш код удобочитаемым, потому что лень в него вчитываться, пытаясь понять, что же все-таки там происходит. В конечном итоге от лени мы стараемся дробить свой код на процедуры и функции так, чтобы его можно было использовать в последующих разработках уже не заморачиваясь отладкой куска, который всегда отлично работал и продолжает работать. И именно от лени многие из нас создают разного рода универсализмы.

Эту статью меня сподвиг написать один из посетителей Инфостарта, когда в комментариях темы о полезных функциях и процедурах я забросил текст небольшого модуля для подключения к управляемым формам объектов данных, связанных с этими объектами и хранимых в регистрах сведений. Почти сразу нашелся желающий прочесть подробнее и в отдельной статье, поэтому решил немножко потрудиться на благо публики и расписать подробнее.   Актуально это решение в первую очередь для нетиповых конфигураций или подсистем, имеющихся в нашем распоряжении.

Без регистров сведений сегодня сложно представить  какую-либо конфигурацию. Эта довольно несложная для понимания группа метаданных одновременно представляет собой мощное средство для решения возникающих у 1С-ника задач. Реквизиты компаний имеют свойство иногда меняться? – смотрим в сторону Регистров сведений.  Хотим учитывать подходящую к оборудованию номенклатуру запчастей? Снова к регистрам сведений. И не предлагайте табличные части, ведь менеджер, который закупает запчасти, тоже захочет оценить куда они подходят, когда сообразит, что ему это весьма полезно. Вот тогда с табличной частью-то и намучаемся.

Есть и менее очевидные вещи – если пересадить в 1С фанатичных любителей Excel, независимо от того добровольно  для них это было или нет, очень быстро появляются те, кому не нравится для редактирования документов открывать их в отдельной форме. Помучавшись с чтением / записью этих документов при активизации строки скоро начинаешь понимать – а ведь проще работая с такими господами ничего кроме номера, даты и пары реквизитов,  которые в здравом уме после его создания никто не соберется править, в самом документе не иметь (о документе говорим нестандартном, конечно же) а всё, что господа там дозаполняют по 20 раз на день  вынести все в тот же регистр сведений. Ну а если господа выдумали некую группу показателей, которую даже теоретически должны видеть только три человека, в то время как все остальные – половина пользователей, сами Боги велели вынести эти показатели в отдельную табличку, и естественно это будет регистр сведений.
Еще одно из решений, связанных с использованием регистров сведений, к которому пришел я (и вполне допускаю, что и еще много кто), причем задолго до появления таких технологий, как расширения, это вынесение в них нетиповой информации вместо добавления реквизитов или табличных частей  к основным объектам.  В свое время даже делал публикацию публикацию на эту тему.

Скрывать нечего, в моем случае наиболее богатым на всяческие дополняющие таблички оказался справочник номенклатуры. Помимо уже имеющихся из коробки УПП, касающихся его регистров сведений, добавлены еще несколько своих. Информация, хранимая в них, поделена на логически законченные блоки: один регистр хранит параметры, которые имеют значение при планировании закупок запчастей и материалов для ремонта оборудования, другой – сведения о размерах упаковок продукции предприятия, третий – необходимые для интеграции с головными предприятием параметры ну и т.д. У каждой подобной таблицы свой круг пользователей, которых интересует их участок, но соседний для них что-то слишком заумное и «лишнее». Естественно, что «лишнее» нужно прятать, а еще лучше вообще ограничить к нему доступ. Группировка данных в регистры сведений «по тематике»  тут оказывается очень кстати. Возьмем, к примеру, такие:

 

 

Положим, со структурой данных определились, насоздавали регистров в конфигурации, но что делать с интерфейсом? Ведь пользователя, который в восторге от того, что для занесения данных нужно пробежаться по нескольким таблицам найти очень сложно. Пользователю удобно, когда все в одном окне – открыл, скажем, все ту же номенклатуру и увидел все, что о ней интересно знать, а что и как там хранится в недрах базы ну совершенно не интересно. Решение есть, и оно весьма простое. В зависимости от того имитируем для пользователя набор реквизитов объекта или его табличную часть, на форму объекта добавляем реквизиты типа «РегистрСведенийМенеджерЗаписей» или «РегистрСведенийНаборЗаписей» размещаем на форме Элементы как захочется, в событии формы «ПриСозданииНаСервере» обеспечиваем их прочтение, в событии «ПослеЗаписиНаСервере» - запись.

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
	
	Если ЗначениеЗаполнено(Объект.Ссылка) Тогда
		ПрочитатьРазмеры();	
		ПрочитатьПрименимость();
	КонецЕсли;	
	
КонецПроцедуры

&НаСервере
Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи) 
	
	Если ЗначениеЗаполнено(Объект.Ссылка) Тогда
		ЗаписатьРазмеры();
		ЗаписатьПрименимость();
	КонецЕсли;	
	
КонецПроцедуры

&НаСервере
Процедура ПрочитатьРазмеры()

	Если ЗначениеЗаполнено(Номенклатура) Тогда
		
		Запрос = Новый Запрос;
		
		Запрос.Текст = 
		
		//Запись может быть только одна, если никто не добавит лишних измерений
		"ВЫБРАТЬ ПЕРВЫЕ 1
		|	inf_РазмерыОбъектов.Объект,
		|	inf_РазмерыОбъектов.ОбъемЕдиницы,
		|	inf_РазмерыОбъектов.ДлинаЕдиницы,
		|	inf_РазмерыОбъектов.ШиринаЕдиницы,
		|	inf_РазмерыОбъектов.ВысотаЕдиницы,
		|	inf_РазмерыОбъектов.ВесБруттоУпаковки,
		|	inf_РазмерыОбъектов.ТипоразмерУпаковки,
		|	inf_РазмерыОбъектов.РядовНаПаллете,
		|	inf_РазмерыОбъектов.ВесНеттоСух
		|ИЗ
		|	РегистрСведений.inf_РазмерыОбъектов КАК inf_РазмерыОбъектов
		|ГДЕ
		|	inf_РазмерыОбъектов.Объект = &Объект"
		;
		
		Запрос.УстановитьПараметр("Объект", Номенклатура); 
		
		Выборка = Запрос.Выполнить().Выбрать();
		
		Если Выборка.Следующий() Тогда
			ЗаполнитьЗначенияСвойств(РазмерыОбъектов, Выборка);
		КонецЕсли;	

		РазмерыОбъектов.Объект = Номенклатура;
		
	КонецЕсли;	
	
КонецПроцедуры	

&НаСервере
Процедура ЗаписатьРазмеры()

	МенеджерЗаписи = РеквизитФормыВЗначение("РазмерыОбъектов");
	
	МенеджерЗаписи.Объект = Номенклатура;
	
	ЕстьЗаполненные = ПроверитьЗаполненностьРесурсовЗаписиРС(МенеджерЗаписи, "inf_РазмерыОбъектов");
	
	Если ЕстьЗаполненные Тогда
		Попытка
			МенеджерЗаписи.Записать();	
		Исключение	
		КонецПопытки;	
	Иначе
		Попытка
			МенеджерЗаписи.Удалить();	
		Исключение	
		КонецПопытки;	
	КонецЕсли;
	
КонецПроцедуры

&НаСервере
Процедура ПрочитатьПрименимость()
		
	НаборЗаписей  = РегистрыСведений.inf_ПрименимостьНоменклатуры.СоздатьНаборЗаписей();	
	НаборЗаписей.Отбор.Номенклатура.Установить(Номенклатура);
	НаборЗаписей.Прочитать();
	
	ЗначениеВРеквизитФормы(НаборЗаписей, "Применимость");
	
КонецПроцедуры	

&НаСервере
Процедура ЗаписатьПрименимость()
	
	Если Не ЗначениеЗаполнено(Номенклатура) Тогда
		Возврат;	
	КонецЕсли;	
	
	НаборЗаписей = РеквизитФормыВЗначение("Применимость");
	
	Т = НаборЗаписей.Выгрузить();
	
	НаборЗаписей.Отбор.Номенклатура.Установить(Номенклатура);
	//НаборЗаписей.Прочитать();
	НаборЗаписей.Загрузить(Т);
	
	Для Каждого Стр Из НаборЗаписей Цикл
		Стр.Номенклатура = Номенклатура;	
	КонецЦикла;
	
	Попытка		
		НаборЗаписей.Записать();		
	Исключение
	КонецПопытки;
	
КонецПроцедуры	


В общем-то, для тех, кто успешно преодолел уровень новичка,  тут все просто, понятно и даже рутинно. Какое-то время я так и делал. Но довольно быстро понял – подобная рутина отнимает не то, чтобы сильно много времени, но происходит это обязательно в те моменты, когда хоть какой-то результат нужно выдать вчера. Ну и банально – лень это каждый раз писать или копипастить/ поправлять, тем более после недолгой обкатки приема с регистрами сведений, их количество и области применения в конфигурации стали разрастаться, как грибы после летнего дождя. Тогда, выкроив несколько свободных часов, и взялся за очередной универсализм. Так родился небольшой модуль, позволяющий минимизировать трудозатраты на описание чтения / записи присоединенных к формам объектов регистров. Принцип потратить пару часов сейчас, но выиграть десятки потом, сработал на ура. Так родился небольшой модуль следующего содержания:

Процедура ПрочитатьНаборЗаписейРС(УпрФорма, ИмяРегистра, СтруктураОтбора, ИмяРеквизитаУФ = Неопределено) Экспорт
	
	Если ИмяРеквизитаУФ = Неопределено Тогда
		ИмяРеквизитаУФ = ИмяРегистра;	
	КонецЕсли;	
	
	Запрос = ПодготовитьЗапросНаЧтениеРегистраСведений(ИмяРегистра, СтруктураОтбора);
	
	Выборка = Запрос.Выполнить().Выбрать();
	НаборЗаписейУФ = УпрФорма[ИмяРеквизитаУФ];
	
	НаборЗаписейУФ.Очистить();
	
	Пока Выборка.Следующий() Цикл
		СтрНабора = НаборЗаписейУФ.Добавить();
		ЗаполнитьЗначенияСвойств(СтрНабора, Выборка);
	КонецЦикла;	
		
КонецПроцедуры	

Процедура ЗаписатьНаборЗаписейРС(УпрФорма, ИмяРегистра, СтруктураОтбора,
				ИмяРеквизитаУФ = Неопределено, ЗначенияЗаполнения = Неопределено)  Экспорт
	
	Если ИмяРеквизитаУФ = Неопределено Тогда
		ИмяРеквизитаУФ = ИмяРегистра;	
	КонецЕсли;
	
	Если ЗначенияЗаполнения = Неопределено Тогда
		ЗначенияЗаполнения = Новый Структура;
	КонецЕсли;	
	
	НаборЗаписей = РегистрыСведений[ИмяРегистра].СоздатьНаборЗаписей();
	
	Для Каждого Парам Из СтруктураОтбора Цикл
		НаборЗаписей.Отбор[Парам.Ключ].Установить(Парам.Значение);
	КонецЦикла;
	
	//НаборЗаписей.Прочитать();
	//НаборЗаписей.Очистить();

	НаборЗаписейУФ = УпрФорма[ИмяРеквизитаУФ];

	Для Каждого Стр Из НаборЗаписейУФ Цикл
		СтрНабора = НаборЗаписей.Добавить();
		ЗаполнитьЗначенияСвойств(СтрНабора, Стр);
		
		Для Каждого Парам Из СтруктураОтбора Цикл
			СтрНабора[Парам.Ключ] = Парам.Значение;	
		КонецЦикла;	
		
		Для Каждого Зн Из ЗначенияЗаполнения Цикл
			Если Не ЗначениеЗаполнено(СтрНабора[Зн.Ключ]) Тогда
				СтрНабора[Зн.Ключ] = Зн.Значение;	
			КонецЕсли;
		КонецЦикла;	
		
	КонецЦикла;	
	
	НаборЗаписей.Записать();
	
КонецПроцедуры	

Процедура ПрочитатьМенеджерЗаписиРС(УпрФорма, ИмяРегистра, СтруктураОтбора, ИмяРеквизитаУФ = Неопределено) Экспорт

	Если ИмяРеквизитаУФ = Неопределено Тогда
		ИмяРеквизитаУФ = ИмяРегистра;	
	КонецЕсли;	

	МенеджерЗаписиУФ = УпрФорма[ИмяРеквизитаУФ];
	
	Запрос = ПодготовитьЗапросНаЧтениеРегистраСведений(ИмяРегистра, СтруктураОтбора);
	Выборка = Запрос.Выполнить().Выбрать();

	Если Выборка.Следующий() Тогда
		ЗаполнитьЗначенияСвойств(МенеджерЗаписиУФ, Выборка);
	Иначе
		ПустойМенеджерЗаписи = РегистрыСведений[ИмяРегистра].СоздатьМенеджерЗаписи();
		ЗаполнитьЗначенияСвойств(МенеджерЗаписиУФ, ПустойМенеджерЗаписи);
	КонецЕсли;	
	
КонецПроцедуры	

Процедура ЗаписатьМенеджерЗаписейРС(УпрФорма, ИмяРегистра, СтруктураОтбора,
				ИмяРеквизитаУФ = Неопределено, ЗначенияЗаполнения = Неопределено)  Экспорт
				
	ПроверитьЗаполнение = СтруктураНеключевыхПолейРС(ИмяРегистра, СтруктураОтбора);			
				
	Если ИмяРеквизитаУФ = Неопределено Тогда
		ИмяРеквизитаУФ = ИмяРегистра;	
	КонецЕсли;
	
	Если ЗначенияЗаполнения = Неопределено Тогда
		ЗначенияЗаполнения = Новый Структура;
	КонецЕсли;	
	
	МенеджерЗаписиУФ = УпрФорма[ИмяРеквизитаУФ];
	МенеджерЗаписи = РегистрыСведений[ИмяРегистра].СоздатьМенеджерЗаписи();
	
	ЗаполнитьЗначенияСвойств(МенеджерЗаписи, МенеджерЗаписиУФ);
	
	Для Каждого Парам Из СтруктураОтбора Цикл
		МенеджерЗаписи[Парам.Ключ] = Парам.Значение;	
	КонецЦикла;

	Для Каждого Зн Из ЗначенияЗаполнения Цикл
		Если Не ЗначениеЗаполнено(МенеджерЗаписи[Зн.Ключ]) Тогда
			МенеджерЗаписи[Зн.Ключ] = Зн.Значение;	
		КонецЕсли;
	КонецЦикла;	
	
	Писать = Ложь;
	Для Каждого Поле Из ПроверитьЗаполнение Цикл
		Если ЗначениеЗаполнено(МенеджерЗаписи[Поле.Ключ]) Тогда
			Писать = Истина;
			Прервать;	
		КонецЕсли;	
	КонецЦикла;	
	
	Если Писать Тогда
		МенеджерЗаписи.Записать();
	Иначе
		МенеджерЗаписи.Удалить();
	КонецЕсли;
	
КонецПроцедуры

//ИмяРегистра - Имя регистра сведений, для которого читается набор
//СтруктураОтбора - Значения измерений, по которым фильтруются записи
//МенеджерЗаписи - При чтении в менеджер записи - реквизит формы,
Функция ПодготовитьЗапросНаЧтениеРегистраСведений(ИмяРегистра, СтруктураОтбора)
	
	Запрос = Новый Запрос;
	
	ТекстЗапроса = 
	
	"ВЫБРАТЬ
	|
	|&Поля
	|
	|ИЗ РегистрСведений.&ИмяРегистра КАК Т
	|
	|ГДЕ &УсловияОтбора
	|"
	;
	
	ТекстПоля = "";
	МетаданныеРС = Метаданные.РегистрыСведений[ИмяРегистра];
	
	Для Каждого Изм Из МетаданныеРС.Измерения Цикл
		ТекПоле = "Т." + Изм.Имя;
		Если ТекстПоля = "" Тогда
			ТекстПоля = ТекПоле;
		Иначе	
			ТекстПоля = ТекстПоля + "," + Символы.ПС + ТекПоле;
		КонецЕсли;	
		
	КонецЦикла;	
	
	Для Каждого Рес Из МетаданныеРС.Ресурсы Цикл
		ТекПоле = "Т." + Рес.Имя;
		Если ТекстПоля = "" Тогда
			ТекстПоля = ТекПоле;
		Иначе	
			ТекстПоля = ТекстПоля + "," + Символы.ПС + ТекПоле;
		КонецЕсли;
	КонецЦикла;	
	
	Для Каждого Рекв Из МетаданныеРС.Реквизиты Цикл
		ТекПоле = "Т." + Рекв.Имя;
		Если ТекстПоля = "" Тогда
			ТекстПоля = ТекПоле;
		Иначе	
			ТекстПоля = ТекстПоля + "," + Символы.ПС + ТекПоле;
		КонецЕсли;	
	КонецЦикла;	

	Если МетаданныеРС.ПериодичностьРегистраСведений <> Метаданные.СвойстваОбъектов.ПериодичностьРегистраСведений.Непериодический Тогда
		ТекПоле = "Т.Период";
		Если ТекстПоля = "" Тогда
			ТекстПоля = ТекПоле;
		Иначе	
			ТекстПоля = ТекстПоля + "," + Символы.ПС + ТекПоле;
		КонецЕсли;
	КонецЕсли;
	
	ТекстУсловияОтбора = "";
	
	Для Каждого Парам Из СтруктураОтбора Цикл
		ТекОтбор = "Т." + Парам.Ключ + " = &" + Парам.Ключ; 
		
		Если ТекстУсловияОтбора = "" Тогда
			ТекстУсловияОтбора = ТекОтбор;	
		Иначе
			ТекстУсловияОтбора = ТекстУсловияОтбора + Символы.ПС + " И " + ТекОтбор;
		КонецЕсли;	
		
		Запрос.УстановитьПараметр(Парам.Ключ, Парам.Значение);
		
	КонецЦикла;	
	
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&Поля"			, ТекстПоля);
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&ИмяРегистра"		, ИмяРегистра);
	ТекстЗапроса = СтрЗаменить(ТекстЗапроса, "&УсловияОтбора"	, ТекстУсловияОтбора);
	
	Запрос.Текст = ТекстЗапроса;
	
	Возврат Запрос;

КонецФункции

Функция СтруктураНеключевыхПолейРС(ИмяРегистра, СтруктураОтбора)
	
	НеключевыеРеквизиты = Новый Структура;
	МетаданныеРС = Метаданные.РегистрыСведений[ИмяРегистра];
	
	Для Каждого Изм Из МетаданныеРС.Измерения Цикл
		Если Не СтруктураОтбора.Свойство(Изм.Имя) Тогда
			НеключевыеРеквизиты.Вставить(Изм.Имя);
		КонецЕсли;	
	КонецЦикла;	
	
	Для Каждого Рес Из МетаданныеРС.Ресурсы Цикл
		Если Не СтруктураОтбора.Свойство(Рес.Имя) Тогда
			НеключевыеРеквизиты.Вставить(Рес.Имя);
		КонецЕсли;
	КонецЦикла;	
	
	Для Каждого Рекв Из МетаданныеРС.Реквизиты Цикл
		Если Не СтруктураОтбора.Свойство(Рекв.Имя) Тогда
			НеключевыеРеквизиты.Вставить(Рекв.Имя);
		КонецЕсли;
	КонецЦикла;	

	Если МетаданныеРС.ПериодичностьРегистраСведений <> Метаданные.СвойстваОбъектов.ПериодичностьРегистраСведений.Непериодический Тогда
		НеключевыеРеквизиты.Вставить("Период");
	КонецЕсли;
	Возврат НеключевыеРеквизиты;
	
КонецФункции	

 

    Вызывается это так:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)

	СтруктураОтбора = Новый Структура("Номенклатура", Номенклатура);
	inf_РаботаСДиалогамиСервер.ПрочитатьНаборЗаписейРС(ЭтаФорма, "вичи_ПрименимостьНоменклатуры",
		СтруктураОтбора, "Применимость");
	
	СтруктураОтбора2 = Новый Структура("Объект", Номенклатура);
	inf_РаботаСДиалогамиСервер.ПрочитатьМенеджерЗаписиРС(ЭтаФорма, "inf_РазмерыОбъектов",
			СтруктураОтбора2, "РазмерыОбъектов");
КонецПроцедуры

&НаСервере
Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи) 

	СтруктураОтбора = Новый Структура("Номенклатура", Объект.Ссылка);
	ЗначенияЗаполнения = Новый Структура("Назначение",
			ПредопределенноеЗначение("Перечисление.inf_НазначенияИспользованияНоменклатуры.ТехническоеОбслуживание"));
		
	inf_РаботаСДиалогамиСервер.ЗаписатьНаборЗаписейРС(ЭтаФорма,  "inf_ПрименимостьНоменклатуры", СтруктураОтбора,
				"Применимость", ЗначенияЗаполнения);

	СтруктураОтбора2 = Новый Структура("Объект", Номенклатура);	
	inf_РаботаСДиалогамиСервер.ЗаписатьМенеджерЗаписейРС(ЭтаФорма, "inf_РазмерыОбъектов",
			СтруктураОтбора2, "РазмерыОбъектов");

КонецПроцедуры

 
Основных процедур получилось четыре: ПрочитатьНаборЗаписейРС, ЗаписатьНаборЗаписейРС, ПрочитатьМенеджерЗаписиРС, ЗаписатьМенеджерЗаписейРС с почти идентичными параметрами:

  • УпрФорма – форма, к которой выполняем подключение, обязательный параметр
  • ИмяРегистра – Имя регистра сведений в дереве метаданных, обязательный параметр
  • СтруктураОтбора – ключ структуры аналогичен имени измерения регистра, по которому требуется отфильтровать записи, значение – собственно значение, по которому фильтруем, обязательный параметр
  • ИмяРеквизитаУФ – Имя реквизита на переданной в первом параметре форме, в который / из которого нужно выполнить чтение / запись, необязательный параметр, если не задан, имя реквизита будет считаться идентичным имени регистра (второй параметр)
  • ЗначенияЗаполнения – есть только в процедурах записи, позволяет автоматически проставить значения ресурсов и реквизитов регистра, которыми пользователь не управляет, но они требуются нам для корректной работы системы.

Теперь получается много удобнее и быстрее. Больше не нужно расписывать очередной регистр, интегрируя его на форму, пару строк и все, что нужно прочитано и в нужный момент записано. Справедливости ради, должен заметить, что покрывая 99% подобных задач, всеобщей панацеей это решение все-таки не является. Исключением будут те редкие случаи, когда в редактировании одного и того же объекта одновременно участвуют несколько пользователей. В таком режиме остается место для ситуации, когда один из пользователей открывает объект и долго-нудно его поправляет. В это время второй открывает, быстро вносит свою лепту и сохраняет. Когда же первый заканчивает, он записывает свою версию, в том числе затерев то, что сделал его коллега. Вероятность такой ситуации всегда нужно учитывать. Если в нашей номенклатуре она нулевая, то в гипотетической системе управления задачами она вполне реальна. На те случаи выход тоже есть и заключается в использовании динамических списков с отборами, но это уже отдельная история со своей спецификой и своими подводными камнями.

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо развёрнутое
Свернуть все
1. VmvLer 19.05.20 17:23 Сейчас в теме
хромой велик.
зачем писать свою посдсистему управления свойствами?

в скомканном изложении идей тщетно пытался найти ответ, чуть не уснул

перл
Исключением будут те редкие случаи, когда в редактировании одного и того же объекта одновременно участвуют несколько пользователей.


Это не редкие случаи, а очень частые и одна из основных фантомных болей разрабов от платформы к платформы.
triera2000; BigB; +2 Ответить
2. ardn 99 19.05.20 17:35 Сейчас в теме
Вы изобрели... дополнительные свойства?
ZLENKO; triera2000; BigB; +3 Ответить
3. Infector 156 19.05.20 17:57 Сейчас в теме
(2)
(1)
Это не есть дополнительные свойства. Мне известно о таковых, но восторга не вызывают никакого. Чаще всего много удобнее вместо "Свойств" в классическом виде (т.е. Объект и Свойство как измерения и Значение как ресурс) иметь регистр с единственным измерением, а вместо второго измерения и его значений - несколько ресурсов. Многое из хранимого в этих доп. регистрах используется в обработках, например для планирования, и в них "свойства" оказываются только лишней морокой. Хотя бы потому что их или придется делать предопределенными и затем морочится описанием 100500 соединений для запроса, или морочиться с хитрыми обходами результата, или заниматься костылями вроде Запрос.УстановитьПараметр("Свойство", ПланыВидовХарактеристик.СвойстваОбъектов.НайтиПоНаименованию("ЧтоТоТам"))
Это мнение субъективно и сформировано с колокольни моих задач.

Второй случай - свойствами вообще не описывается. Имеем измерение, соответствующее объекту, который редактируем и N иных измерений (в том числе и более двух в сумме). На форме все это выражается набором записей. Ресурсов и реквизитов мы опять же имеем не один, а множество.


(1)
Это не редкие случаи, а очень частые и одна из основных фантомных болей разрабов от платформы к платформы.

Тут наверное, действительно так. Но в своей практике сталкивался только раз с тем, чтобы несколько человек одновременно пытались править один и тот же документ. Ну и чаще всего подобным фокусом пользуюсь в связках Справочник - Регистр, а там таких проблем не возникает.
4. dhurricane 19.05.20 21:17 Сейчас в теме
Уж простите мое занудство и претензии к деталям, а не к концепции. Но как говорится, "наболело".

1. Не нужно читать только что созданный набор записей перед его очисткой. Это бесполезное действие, напрасно растрачивающие ресурсы СУБД.
НаборЗаписей.Прочитать();
НаборЗаписей.Очистить();

2. Не нужно читать набор данных и перед загрузкой его из таблицы значений. Это также совершенно бесполезное дело.
НаборЗаписей.Прочитать();
НаборЗаписей.Загрузить(ТЗ);
triera2000; ardn; BigB; +3 Ответить
7. Infector 156 20.05.20 00:10 Сейчас в теме
(4)Пожалуй соглашусь. Можно и без Прочитать() и без Очистить().
5. Vortigaunt 76 19.05.20 21:22 Сейчас в теме
Я правильно понимаю, что если открыть карточку номенклатуры и поменять в ней только поля, относящиеся к регистру сведений, то модифицированность не включится, событие ПослеЗаписи не сработает. И после "ОК" карточка просто закроется и данные в регистр сведений не запишутся?
Тогда может завести в номенклатуре флажок, который дергать при изменении набора записей или менеджера регистра, размещенных на форме.
Тогда и модифицированность будет, и событие вызовется, и другой пользователь, который тупит над объектом получит при записи сообщение: "данные изменены в другом сеансе" и будет вынужден выйти без сохранения и набивать заново.
6. Infector 156 19.05.20 23:51 Сейчас в теме
(5)флаг "Модифицированность" действительно не проставляется, но событие "ПослеЗаписиНаСервере" отрабатывает невзирая на него. Возможно, что на более свежих версиях платформы что-то изменили и дело обстоит иначе.
8. PowerBoy 2960 20.05.20 07:34 Сейчас в теме
Если надо добавить доп.реквизиты к справочнику я обычно использую подчиненный справочник, с ним проще работать чем с регистрами сведений, да и интерфейс в формах сам настраивается.
9. Infector 156 20.05.20 08:04 Сейчас в теме
(8)Вот тут могу поспорить о том как все-таки лучше. У доп. справочника, как хранителя доп. реквизитов есть куча скрытых подвохов:
1. На уровне структуры данных он не обеспечивает уникальность записей сам по себе. Если одной записи основного справочника, должна соответствовать одна запись подчиненного появляется реквизит в основном справочнике и перекрестная запись. Или же начинаем городить защиту от дурака.
2. У подчиненного Справочника остаются Стандартные реквизиты, хотя по большому счету они никому не нужны. Можно оставить только код или только наименование, но это все равно остается "прицепом", за которым так или иначе придется следить.

Далее - если имитируется табличная часть. Тут с одной стороны есть вещи, где с подчиненным справочником действительно работать правильнее, т.к. это лучше описывает объект (Если говорить о номенклатуре, то те же Единицы измерения) и используется в учете как дополнительная аналитика.
Но с другой - вещи, где это не требуется. И тут нарываемся на еще один подвох:
3. Объектная модель работы со справочником предполагает запись строк таблицы всегда по одной. В то время как в регистр можно писать через "набор записей" разом.
4. Частенько и "периодичность" оказывается включена и при этом весьма полезна.
5. Один и тот же регистр может подключаться к разным объектам по разным измерениям. Пример - прямо в статье. Код приведен со стороны справочника "Номенклатура", но аналогично делается и со стороны справочника "Основные средства"
13. Vortigaunt 76 20.05.20 22:29 Сейчас в теме
(9)
2. У подчиненного Справочника остаются Стандартные реквизиты, хотя по большому счету они никому не нужны. Можно оставить только код или только наименование, но это все равно остается "прицепом", за которым так или иначе придется следить.

А разве не срабатывает фишка:
Длина наименования = 0
Длина кода = 0
Итого нет ни когда ни наименования?
14. Infector 156 21.05.20 07:42 Сейчас в теме
(13)как ни странно, но такой фокус срабатывает. Тем не менее, никуда не девается дополнительная ссылка, без нее уже справочник справочником не будет, а так же не снимается вопрос с обеспечением уникальности без внесения перекрестной ссылки, хотя на программном уровне он и решаем.
10. milanse 34 20.05.20 12:51 Сейчас в теме
С формами объекта все ок, а как добавлять поля во все отчёты и формы списков, чтобы их через точку дергать, допсвойства это делать позволяют. Хотя, конечно я бы хотел именно описанный функционал группы реквизитов для допилки конфы. Но теперь с учётом расширений никто туда смотреть не станет
11. Infector 156 20.05.20 13:33 Сейчас в теме
(10)У нас оказалось с этим проще - отчеты и формы списков, где таковые доработки использованы нестандартные. Формы а-ля Рабочее место кладовщика технического склада, или менеджера по закупкам технических материалов. А там делается просто, на уровне Левого соединения в запросе.

Еще довелось применить и в полностью нетиповой конфигурации. "Менеджер записи" (т.е. единичная запись регистра) там врят ли когда-то будет востребован, разве что жестким разделением доступа к данным озаботятся, а вот подходящий под описанный принцип "Набор записей" наверное в любой конфигурации можно отыскать. И надо сказать в полностью нетиповых расширения не особо в почете, как минимум надоедает нужные реквизиты из конфы в расширение забрасывать, чтобы они там доступны были.
12. the1 540 20.05.20 22:27 Сейчас в теме
(10) В СКД есть фокус - для поля МойРеквизитИзРегистра пишем в ячейку Путь Номенклатура.МойРеквизитИзРегистра
Оставьте свое сообщение

См. также

Навеяно кризисом

Универсальные обработки WEB Работа с интерфейсом Банковские операции Банковские операции v8 1cv8.cf Бесплатно (free)

Используя эту обработку Вы всегда будете знать состояние кризиса на данный момент :)

11.11.2008    18199    0    ValeriVP    27